Function Reference


_GUICtrlHeader_SetOrderArray

Sets the current left-to-right order of items

#include <GuiHeader.au3>
_GUICtrlHeader_SetOrderArray ( $hWnd, ByRef $aOrder )

Parameters

$hWnd Handle to the control
$aOrder Array that specifies the index values for items in the header:
    [0] - Number of items in array
    [1] - Item index 1
    [2] - Item index 2
    [n] - Item index n

Return Value

Success: True.
Failure: False.

Related

_GUICtrlHeader_GetOrderArray

Example

#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hHeader, $aOrder[5] = [4, 3, 1, 2, 0]

    ; Create GUI
    $hGUI = GUICreate("Header", 400, 300)
    $hHeader = _GUICtrlHeader_Create($hGUI)
    _GUICtrlHeader_SetUnicodeFormat($hHeader, True)
    $g_idMemo = GUICtrlCreateEdit("", 2, 24, 396, 274, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Add columns
    _GUICtrlHeader_AddItem($hHeader, "Column 1", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 2", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 3", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 4", 100)

    ; Set order array
    _GUICtrlHeader_SetOrderArray($hHeader, $aOrder)

    ; Show order array
    $aOrder = _GUICtrlHeader_GetOrderArray($hHeader)
    For $iI = 1 To $aOrder[0]
        MemoWrite("Index: " & $iI - 1 & ", Order: " & $aOrder[$iI] & ' (' & _GUICtrlHeader_GetItemText($hHeader, $iI - 1) & ')')
    Next

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Write a line to the memo control
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite