Function Reference

_GUICtrlListView_EnableGroupView

Enables or disables whether the items in the control display as a group

#include <GuiListView.au3>
_GUICtrlListView_EnableGroupView ( $hWnd [, $bEnable = True] )

Parameters

$hWnd Control ID/Handle to the control
$bEnable [optional] Indicates whether to enable group displayed items
    True - Enable group view
    False - Disable group view

Return Value

0: the ability to display listview items as a group is already enabled or disabled.
1: the state of the control was successfully changed.

Remarks

This function is not supported under the $LVS_OWNERDATA style.

Related

_GUICtrlListView_GetGroupViewEnabled

Example

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>

Example()

Func Example()
        Local $hImage, $idListview

        GUICreate("ListView Enable Group View", 400, 300)
        $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
        GUISetState(@SW_SHOW)

        ; Load images
        $hImage = _GUIImageList_Create()
        _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($idListview), 0xFF0000, 16, 16))
        _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($idListview), 0x00FF00, 16, 16))
        _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($idListview), 0x0000FF, 16, 16))
        _GUICtrlListView_SetImageList($idListview, $hImage, 1)

        ; Add columns
        _GUICtrlListView_InsertColumn($idListview, 0, "Column 1", 100)
        _GUICtrlListView_InsertColumn($idListview, 1, "Column 2", 100)
        _GUICtrlListView_InsertColumn($idListview, 2, "Column 3", 100)

        ; Add items
        _GUICtrlListView_AddItem($idListview, "Row 1: Col 1", 0)
        _GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 2", 1)
        _GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 3", 2)
        _GUICtrlListView_AddItem($idListview, "Row 2: Col 1", 1)
        _GUICtrlListView_AddSubItem($idListview, 1, "Row 2: Col 2", 1)
        _GUICtrlListView_AddItem($idListview, "Row 3: Col 1", 2)

        ; Build groups
        _GUICtrlListView_EnableGroupView($idListview)
        _GUICtrlListView_InsertGroup($idListview, -1, 1, "Group 1")
        _GUICtrlListView_InsertGroup($idListview, -1, 2, "Group 2")
        _GUICtrlListView_SetItemGroupID($idListview, 0, 1)
        _GUICtrlListView_SetItemGroupID($idListview, 1, 2)
        _GUICtrlListView_SetItemGroupID($idListview, 2, 2)

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
EndFunc   ;==>Example