Function Reference


_GUICtrlListView_GetNumberOfWorkAreas

Retrieves the number of working areas in the control

#include <GuiListView.au3>
_GUICtrlListView_GetNumberOfWorkAreas ( $hWnd )

Parameters

$hWnd Control ID/Handle to the control

Return Value

Returns the number of working areas.

Related

_GUICtrlListView_SetWorkAreas

Example

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hImage, $idListview

    GUICreate("ListView Get # of Work Areas", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUICtrlSetStyle($idListview, $LVS_ICON)
    GUISetState(@SW_SHOW)

    ; Load images
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($idListview, $hImage, 0)

    ; Add columns
    _GUICtrlListView_AddColumn($idListview, 0, "Items", 100)

    ; Add items
    _GUICtrlListView_AddItem($idListview, "Item 1", 0)
    _GUICtrlListView_AddItem($idListview, "Item 2", 1)
    _GUICtrlListView_AddItem($idListview, "Item 3", 2)

    ; Create work area
    _GUICtrlListView_SetWorkAreas($idListview, 0, 0, 100, 100)
    MsgBox($MB_SYSTEMMODAL, "Information", "Work Areas: " & _GUICtrlListView_GetNumberOfWorkAreas($idListview))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example