Function Reference


_GUICtrlListView_GetViewTile

Determines whether the view mode is in tile mode

#include <GuiListView.au3>
_GUICtrlListView_GetViewTile ( $hWnd )

Parameters

$hWnd Control ID/Handle to the control

Return Value

True: view is in tile mode.
False: view is not in tile mode.

Related

_GUICtrlListView_GetView

Example

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idListview

    GUICreate("ListView Get View Tile", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Add columns
    _GUICtrlListView_AddColumn($idListview, "Items", 100)

    ; Add items
    _GUICtrlListView_BeginUpdate($idListview)
    For $iI = 1 To 10
        _GUICtrlListView_AddItem($idListview, "Item " & $iI)
    Next
    _GUICtrlListView_EndUpdate($idListview)

    ; Set view
    _GUICtrlListView_SetView($idListview, 4)
    MsgBox($MB_SYSTEMMODAL, "Information", "View Tile: " & _GUICtrlListView_GetViewTile($idListview))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example