Function Reference


_GUICtrlListView_SetItemDropHilited

Sets whether the item is highlighted as a drag-and-drop target

#include <GuiListView.au3>
_GUICtrlListView_SetItemDropHilited ( $hWnd, $iIndex [, $bEnabled = True] )

Parameters

$hWnd Handle to the control
$iIndex 0-based index of the item
$bEnabled [optional] If True the item state is set, otherwise it is not set.

Return Value

Success: True.
Failure: False.

Related

_GUICtrlListView_GetItemDropHilited

Example

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idListview

    GUICreate("ListView Set Item Drop Hilited", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Add columns
    _GUICtrlListView_AddColumn($idListview, "Column 1", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 2", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 3", 100)

    ; Add items
    _GUICtrlListView_AddItem($idListview, "Row 1: Col 1", 0)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 2", 1)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 3", 2)
    _GUICtrlListView_AddItem($idListview, "Row 2: Col 1", 1)
    _GUICtrlListView_AddSubItem($idListview, 1, "Row 2: Col 2", 1)
    _GUICtrlListView_AddItem($idListview, "Row 3: Col 1", 2)

    ; Hilight item 2
    _GUICtrlListView_SetItemDropHilited($idListview, 1)
    MsgBox($MB_SYSTEMMODAL, "Information", "Item 2 Drop Hilited: " & _GUICtrlListView_GetItemDropHilited($idListview, 1))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example