Function Reference


_GUICtrlMenu_GetItemChecked

Retrieves the status of the menu item checked state

#include <GuiMenu.au3>
_GUICtrlMenu_GetItemChecked ( $hMenu, $iItem [, $bByPos = True] )

Parameters

$hMenu Handle of the menu
$iItem Identifier or position of the menu item
$bByPos [optional] Menu identifier flag:
    True - $iItem is a 0-based item position
    False - $iItem is a menu item identifier

Return Value

True: the item is checked.
False: the item is not checked.

Related

_GUICtrlMenu_SetItemChecked

Example

#include <GuiMenu.au3>

Example()

Func Example()
    Local $hWnd, $hMain, $hFile

    ; Open Notepad
    Run("notepad.exe")
    WinWaitActive("[CLASS:Notepad]")
    $hWnd = WinGetHandle("[CLASS:Notepad]")
    $hMain = _GUICtrlMenu_GetMenu($hWnd)
    $hFile = _GUICtrlMenu_GetItemSubMenu($hMain, 0)

    ; Check Open menu item
    Writeln("Open is checked: " & _GUICtrlMenu_GetItemChecked($hFile, 1))
    _GUICtrlMenu_SetItemChecked($hFile, 1)
    Writeln("Open is checked: " & _GUICtrlMenu_GetItemChecked($hFile, 1))
EndFunc   ;==>Example

; Write a line of text to Notepad
Func Writeln($sText)
    ControlSend("[CLASS:Notepad]", "", "Edit1", $sText & @CRLF)
EndFunc   ;==>Writeln