Function Reference


_GUICtrlMenu_GetItemEnabled

Retrieves the status of the menu item enabled state

#include <GuiMenu.au3>
_GUICtrlMenu_GetItemEnabled ( $hMenu, $iItem [, $bByPos = True] )

Parameters

$hMenu Handle of the menu
$iItem Identifier or position of the menu item
$bByPos [optional] Menu identifier flag:
    True - $iItem is a 0-based item position
    False - $iItem is a menu item identifier

Return Value

True: $iItem is enabled.
False: $iItem is not enabled

Related

_GUICtrlMenu_SetItemEnabled

Example

#include <GuiMenu.au3>

Example()

Func Example()
    Local $hWnd, $hMain, $hFile

    ; Open Notepad
    Run("notepad.exe")
    WinWaitActive("[CLASS:Notepad]")
    $hWnd = WinGetHandle("[CLASS:Notepad]")
    $hMain = _GUICtrlMenu_GetMenu($hWnd)
    $hFile = _GUICtrlMenu_GetItemSubMenu($hMain, 0)

    ; Get/Set Open enabled
    Writeln("Open is disabled: " & _GUICtrlMenu_GetItemDisabled($hFile, 1))
    _GUICtrlMenu_SetItemDisabled($hFile, 1)
    Writeln("Open is disabled: " & _GUICtrlMenu_GetItemDisabled($hFile, 1))
    _GUICtrlMenu_SetItemEnabled($hFile, 1)
    Writeln("Open is enabled : " & _GUICtrlMenu_GetItemEnabled($hFile, 1))
EndFunc   ;==>Example

; Write a line of text to Notepad
Func Writeln($sText)
    ControlSend("[CLASS:Notepad]", "", "Edit1", $sText & @CRLF)
EndFunc   ;==>Writeln