Function Reference


_GUICtrlMenu_GetItemType

Retrieves the menu item type

#include <GuiMenu.au3>
_GUICtrlMenu_GetItemType ( $hMenu, $iItem [, $bByPos = True] )

Parameters

$hMenu Handle of the menu
$iItem Identifier or position of the menu item
$bByPos [optional] Menu identifier flag:
    True - $iItem is a 0-based item position
    False - $iItem is a menu item identifier

Return Value

Returns the Menu item type. Can be one or more of the following:
$MFT_BITMAP - Item is displayed using a bitmap
$MFT_MENUBARBREAK - Item is placed on a new line. A vertical line separates the new column from the old.
$MFT_MENUBREAK - Item is placed on a new line. The columns are not separated by a vertical line.
$MFT_OWNERDRAW - Item is owner drawn
$MFT_RADIOCHECK - Item is displayed using a radio button mark
$MFT_RIGHTJUSTIFY - Item is right justified
$MFT_RIGHTORDER - Item cascades from right to left
$MFT_SEPARATOR - Item is a separator

Related

_GUICtrlMenu_SetItemType

Example

#include <GuiMenu.au3>

Example()

Func Example()
    Local $hWnd, $hMain, $hFile

    ; Open Notepad
    Run("notepad.exe")
    WinWaitActive("[CLASS:Notepad]")
    $hWnd = WinGetHandle("[CLASS:Notepad]")
    $hMain = _GUICtrlMenu_GetMenu($hWnd)
    $hFile = _GUICtrlMenu_GetItemSubMenu($hMain, 0)

    ; Change Open item type
    Writeln("Open item type: 0x" & Hex(_GUICtrlMenu_GetItemType($hFile, 1)))
    _GUICtrlMenu_SetItemType($hFile, 1, $MFT_RADIOCHECK)
    _GUICtrlMenu_CheckRadioItem($hFile, 0, 8, 1)
    Writeln("Open item type: 0x" & Hex(_GUICtrlMenu_GetItemType($hFile, 1)))
EndFunc   ;==>Example

; Write a line of text to Notepad
Func Writeln($sText)
    ControlSend("[CLASS:Notepad]", "", "Edit1", $sText & @CRLF)
EndFunc   ;==>Writeln