Function Reference


_GUICtrlMenu_SetItemState

Sets the state of a menu item

#include <GuiMenu.au3>
_GUICtrlMenu_SetItemState ( $hMenu, $iItem, $iState [, $bState = True [, $bByPos = True]] )

Parameters

$hMenu Menu handle
$iItem Identifier or position of the menu item
$iState Menu item state:
    $MFS_CHECKED - Item is checked
    $MFS_DEFAULT - Item is the default item
    $MFS_DISABLED - Item is disabled
    $MFS_GRAYED - Item is disabled
    $MFS_HILITE - Item is highlighted
$bState [optional] Item state to set:
    True - State is enabled
    False - State is disabled
$bByPos [optional] Menu identifier flag:
    True - $iItem is a 0-based item position
    False - $iItem is a menu item identifier

Return Value

Success: True.
Failure: False.

Related

_GUICtrlMenu_GetItemState, _GUICtrlMenu_GetItemStateEx

Example

#include <GuiMenu.au3>

Example()

Func Example()
    Local $hWnd, $hMain, $hFile

    ; Open Notepad
    Run("notepad.exe")
    WinWaitActive("[CLASS:Notepad]")
    $hWnd = WinGetHandle("[CLASS:Notepad]")
    $hMain = _GUICtrlMenu_GetMenu($hWnd)
    $hFile = _GUICtrlMenu_GetItemSubMenu($hMain, 0)

    ; Get Open item state
    _GUICtrlMenu_SetItemState($hFile, 1, $MFS_CHECKED)
    Writeln("Open item state: " & _GUICtrlMenu_GetItemStateEx($hFile, 1))
EndFunc   ;==>Example

; Write a line of text to Notepad
Func Writeln($sText)
    ControlSend("[CLASS:Notepad]", "", "Edit1", $sText & @CRLF)
EndFunc   ;==>Writeln