Function Reference


_GUICtrlMonthCal_GetCalendarBorder

Gets the size of the border, in pixels

#include <GuiMonthCal.au3>
_GUICtrlMonthCal_GetCalendarBorder ( $hWnd )

Parameters

$hWnd Control ID/Handle to the control

Return Value

Returns the border size, in pixels.

Remarks

Windows Vista or later.

Related

_GUICtrlMonthCal_SetCalendarBorder

Example

#include <GUIConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $idMonthCal

    ; Create GUI
    GUICreate("Month Calendar", 400, 300)
    $idMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, $WS_BORDER, 0x00000000)

    ; Create memo control
    $g_idMemo = GUICtrlCreateEdit("", 4, 168, 392, 128, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Get/Set calendar border
    MemoWrite("Border in pixels: " & _GUICtrlMonthCal_GetCalendarBorder($idMonthCal))
    Sleep(3000)
    GUISetState(@SW_LOCK)
    _GUICtrlMonthCal_SetCalendarBorder($idMonthCal, 2)
    MemoWrite("Border in pixels: " & _GUICtrlMonthCal_GetCalendarBorder($idMonthCal))
    GUISetState(@SW_UNLOCK)
    Sleep(3000)
    GUISetState(@SW_LOCK)
    _GUICtrlMonthCal_SetCalendarBorder($idMonthCal, 0, False)
    MemoWrite("Border in pixels: " & _GUICtrlMonthCal_GetCalendarBorder($idMonthCal))
    GUISetState(@SW_UNLOCK)

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Write message to memo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite