Function Reference


_GUICtrlMonthCal_GetMinReqRect

Retrieves the minimum size required to display a full month

#include <GuiMonthCal.au3>
_GUICtrlMonthCal_GetMinReqRect ( $hWnd )

Parameters

$hWnd Control ID/Handle to the control

Return Value

Returns a $tagRECT structure.

Related

$tagRECT, _GUICtrlMonthCal_GetMinReqHeight, _GUICtrlMonthCal_GetMinReqWidth

Example

#include <GUIConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $tRECT, $idMonthCal

    ; Create GUI
    GUICreate("Month Calendar Get Min Req Rect", 400, 300)
    $idMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, BitOR($WS_BORDER, $MCS_MULTISELECT), 0x00000000)

    ; Create memo control
    $g_idMemo = GUICtrlCreateEdit("", 4, 168, 392, 128, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Get minimum required height/width
    $tRECT = _GUICtrlMonthCal_GetMinReqRect($idMonthCal)
    MemoWrite("Minimum required height: " & DllStructGetData($tRECT, "Bottom"))
    MemoWrite("Minimum required width : " & DllStructGetData($tRECT, "Right"))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Write message to memo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite