Function Reference


_GUICtrlMonthCal_GetMonthDelta

Retrieves the scroll rate for a month calendar control

#include <GuiMonthCal.au3>
_GUICtrlMonthCal_GetMonthDelta ( $hWnd )

Parameters

$hWnd Control ID/Handle to the control

Return Value

Returns an INT value as follow:
the month calendar's current scroll rate, if the month delta was previously set using the _GUICtrlMonthCal_SetMonthDelta().
the current number of months visible, if the month delta was not previously set using the _GUICtrlMonthCal_SetMonthDelta() or the month delta was reset to the default.

Related

_GUICtrlMonthCal_SetMonthDelta

Example

#include <GUIConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $idMonthCal

    ; Create GUI
    GUICreate("Month Calendar Get Month Delta", 400, 300)
    $idMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, BitOR($WS_BORDER, $MCS_MULTISELECT), 0x00000000)

    ; Create memo control
    $g_idMemo = GUICtrlCreateEdit("", 4, 168, 392, 128, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Get/Set month delta
    _GUICtrlMonthCal_SetMonthDelta($idMonthCal, 2)
    MemoWrite("Month delta: " & _GUICtrlMonthCal_GetMonthDelta($idMonthCal))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Write message to memo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite