Function Reference


_GUICtrlMonthCal_GetRangeMinStr

Retrieves the lower limit date range in string form

#include <GuiMonthCal.au3>
_GUICtrlMonthCal_GetRangeMinStr ( $hWnd [, $sFormat = "%02d/%02d/%04d"] )

Parameters

$hWnd Control ID/Handle to the control
$sFormat [optional] StringFormat string used to format the date

Return Value

Returns a date in the specified format.

Related

_GUICtrlMonthCal_GetRange, _GUICtrlMonthCal_GetRangeMin

Example

#include <GUIConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $idMonthCal

    ; Create GUI
    GUICreate("Month Calendar Get Range Min String", 400, 300)
    $idMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, BitOR($WS_BORDER, $MCS_MULTISELECT), 0x00000000)

    ; Create memo control
    $g_idMemo = GUICtrlCreateEdit("", 4, 168, 392, 128, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Get range
    _GUICtrlMonthCal_SetRange($idMonthCal, @YEAR, 1, 1, @YEAR, 12, 31)
    MemoWrite("Minimum selectable date: " & _GUICtrlMonthCal_GetRangeMinStr($idMonthCal))
    MemoWrite("Maximum selectable date: " & _GUICtrlMonthCal_GetRangeMaxStr($idMonthCal))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Write message to memo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite