Function Reference


_GUICtrlRichEdit_FindText

Search for a text starting at insertion point or at anchor point of selection

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_FindText ( $hWnd, $sText [, $bForward = True [, $bMatchCase = False [, $bWholeWord = False [, $iBehavior = 0]]]] )

Parameters

$hWnd Handle to the control
$sText Text to find
$bForward [optional] Search direction
(Win 95: search is always forward)
$bMatchCase [optional] Search is case-sensitive
Default: case-insensitive
$bWholeWord [optional] Search only for text as a whole word
Default: partial or full word
$iBehavior [optional] Any BitOR combination of $FR_MATCHALEFHAMZA, $FR_MATCHDIAC and $FR_MATCHKASHIDA
Default: 0

Return Value

Success: the inter-character position before start of matching text if found, else -1.
Failure: sets the @error flag to non-zero.
@error: 101 - $hWnd is not a handle
102 - $sText = ""
103 - $bForward is neither True nor False
104 - $bMatchCase is neither True nor False
105 - $bWholeWord is neither True nor False
1061 - $iBehavior is not a number
1062 - $iBehavior is invalid

Related

_GUICtrlRichEdit_FindTextInRange

See Also

Search EM_FINDTEXT in MSDN Library.

Example

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $hRichEdit, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_AppendText($hRichEdit, @CRLF & "This is appended text.")

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; needed unless script crashes
                ; GUIDelete()   ; is OK too
                Exit
            Case $iMsg = $idBtnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_SetSel($hRichEdit, 8, 8)
                        Report("1.set starting position ")
                    Case 2
                        Report('2."appended" found just after inter-character position ' & _
                                _GUICtrlRichEdit_FindText($hRichEdit, "appended"))
                        GUICtrlSetState($idBtnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Example

Func Report($sMsg)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report