Function Reference


_GUICtrlRichEdit_GetCharAttributes

Returns attributes of selected text

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetCharAttributes ( $hWnd )

Parameters

$hWnd Handle to the control

Return Value

Success: a string consisting of three-character groups. Each group consists of:
first and second character: any of:
    bo - bolded
    di - disabled - characters displayed with a shadow [nd]
    em - embossed [nd]
    hi - hidden, i.e. not displayed
    im - imprinted [nd]
    it - italcized
    li - EN_LINK messages are sent when mouse is over text with this attribute
    ou - outlined [nd]
    pr - EN_PROTECT sent when user attempts to modify
    re - marked as revised [nd]
    sh - shadowed [nd]
    sm - small capital letters [nd]
    st - struck out
    sb - subscript [nd]
    sp - superscript [nd]
    un - underlined
third character: + for on, ~ for mixed
Failure: "" and sets the @error flag to non-zero.
@error: 101 - $hWnd is not a handle
-1 - no text is selected

Remarks

Some attributes do not display in a Rich Edit control; they are marked with [nd] above.

Returns "" if no attributes are on

Related

_GUICtrlRichEdit_SetCharAttributes

See Also

Search EM_GETCHARFORMAT in MSDN Library.

Example

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg

Example()

Func Example()
    Local $hGui, $iMsg, $iCp1, $hRichEdit
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_AutoDetectURL($hRichEdit, True)
    _GUICtrlRichEdit_AppendText($hRichEdit, @CRLF & "http://www.autoitscript.com")
    $iCp1 = _GUICtrlRichEdit_GetFirstCharPosOnLine($hRichEdit, 2)
    _GUICtrlRichEdit_SetSel($hRichEdit, $iCp1, $iCp1 + 3)
    Report("Character attributes at start of line 2 are " & _
            _GUICtrlRichEdit_GetCharAttributes($hRichEdit))
    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; needed unless script crashes
                ; GUIDelete()   ; is OK too
                Exit
        EndSelect
    WEnd
EndFunc   ;==>Example

Func Report($sMsg)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report