Function Reference


_GUICtrlRichEdit_GetCharPosOfPreviousWord

Gets inter-character position before the Previous word

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetCharPosOfPreviousWord ( $hWnd, $iCpStart )

Parameters

$hWnd Handle to the control
$iCPStart inter-character position to start from

Return Value

Success: the inter-character position before previous word.
Failure: 0 and sets the @error flag to non-zero.
@error: 101 - $hWnd is not a handle
102 - $iCpStart is not a number

Remarks

"Word" is defined broadly; it includes punctuation, parentheses and hyphens.

Related

_GUICtrlRichEdit_GetCharPosOfNextWord, _GUICtrlRichEdit_GetCharWordBreakInfo

See Also

Search EM_FINDWORDBREAK in MSDN Library.

Example

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $idLblMsg, $hRichEdit, $iCp = 200
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_AppendText($hRichEdit, "AutoIt v3 is a freeware BASIC-like scripting language designed for " _
             & "automating the Windows GUI and general scripting.")

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; needed unless script crashes
                ; GUIDelete()   ; is OK too
                Exit
            Case $iMsg = $idBtnNext
                $iCp = _GUICtrlRichEdit_GetCharPosOfPreviousWord($hRichEdit, $iCp)
                GUICtrlSetData($idLblMsg, $iCp)
                _GUICtrlRichEdit_GotoCharPos($hRichEdit, $iCp)
        EndSelect
    WEnd
EndFunc   ;==>Example