Function Reference


_GUICtrlRichEdit_GetLineNumberFromCharPos

Retrieves the line number on which an inter-character position is found

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetLineNumberFromCharPos ( $hWnd, $iCharPos )

Parameters

$hWnd Handle to the control
$iCharPos Inter-character position

Return Value

Success: the line number (1-based).
Failure: 0 and sets the @error flag to non-zero.
@error: 101 - $hWnd is not a handle
102 - $iCharPos is not a positive number

Remarks

A control that contains no text has one line.
The first inter-character position in a control is 0.

The first line is line 1.

If $iCharPos is negative or more than the number of characters in the control, returns the number of lines in the control.

See Also

Search EM_EXLINEFROMCHAR in MSDN Library.

Example

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg

Example()

Func Example()
    Local $hGui, $iMsg, $hRichEdit
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_AppendText($hRichEdit, @CRLF & "This is appended text")
    Report("Inter-character position 30 is on line " & _GUICtrlRichEdit_GetLineNumberFromCharPos($hRichEdit, 30))

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; needed unless script crashes
                ; GUIDelete()   ; is OK too
                Exit
        EndSelect
    WEnd
EndFunc   ;==>Example

Func Report($sMsg)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report