Gets the border settings of (first) selected paragraph or (if no selection) of the current paragraph
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetParaBorder ( $hWnd )
| $hWnd | Handle to the control |
| Success: | settings of first selected paragraph - a string consisting of values separated by semicolons (:): Value 1 - one or more of: l - left border r - right border t - top border b - bottom border i - inside border o - outside border or empty - no border Value 2 - line style - one of: none - no line .75 - 3/4 point 1.5 - 1 1/2 points 2.25 - 2 1/4 points 3 - 3 points 4.5 - 4 1/2 points 6 - 6 points .75d - 1/2 points, double 1.5d - 1 1/2 points, double 2.25d - 2 1/4 points, double .75g - 3/4 point grey .75gd - 3/4 point grey dashed Value 3 - one of: aut - autocolor blk - black blu - blue cyn - cyan grn - green mag - magenta red - red yel - yellow whi - white dbl - dark blue dgn - dark green dmg - dark magenta drd - dark red dyl - dark yellow dgy - dark grey lgy - light grey Value 4 - space between the border and the text (in space units) Value 5 - scope: a - all (or only) selected paragraphs have these settings f - the first selected paragraph has these settings, but other(s) don't c - the current paragraph has these settings |
| Failure: | Empty string and sets the @error flag to non-zero. |
| @error: | 101 - $hWnd is not a handle |
Borders do not show in Rich Edit, but borders created here will show in Word.
_GUICtrlRichEdit_SetParaBorder
Search EM_GETPARAFORMAT in MSDN Library.
#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsStylesConstants.au3>
Global $g_idLbl_Msg, $g_hRichEdit
Example()
Func Example()
Local $hGui, $iMsg, $iStep = 0, $idBtn_Next
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
$g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$g_idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$idBtn_Next = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState(@SW_SHOW)
_GUICtrlRichEdit_AppendText($g_hRichEdit, "First paragraph")
Report("0. First paragraph: default settings")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($g_hRichEdit) ; needed unless script crashes
; GUIDelete() ; is OK too
Exit
Case $iMsg = $idBtn_Next
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_AppendText($g_hRichEdit, @CRLF & "Second paragraph")
_GUICtrlRichEdit_SetParaBorder($g_hRichEdit, "o", 3, "mag", 0.25)
Report("1. Second paragraph: with border (should show in Word)")
Case 2
_GUICtrlRichEdit_SetSel($g_hRichEdit, 10, -1)
Report("2. Settings of first paragraph in selection")
Case 3
_GUICtrlRichEdit_SetParaBorder($g_hRichEdit, "l", 6, "blu")
Report("3. Settings of both paragraphs changed")
Case 4
_GUICtrlRichEdit_SetParaBorder($g_hRichEdit, Default, ".75gd")
Report("4. Line style changed")
Case 5
; Stream all text to the Desktop so you can look at border settings in Word
_GUICtrlRichEdit_Deselect($g_hRichEdit)
_GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetState($idBtn_Next, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Example
Func Report($sMsg)
$sMsg = $sMsg & @CRLF & @CRLF & "Get function returns " & @CRLF & _GUICtrlRichEdit_GetParaBorder($g_hRichEdit)
GUICtrlSetData($g_idLbl_Msg, $sMsg)
EndFunc ;==>Report