Function Reference


_GUICtrlRichEdit_GetParaTabStops

Gets the tabstops of (first) selected paragraph or (if no selection) of the current paragraph

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetParaTabStops ( $hWnd )

Parameters

$hWnd Handle to the control

Return Value

Success: A string consisting of values separated by ; (semicolons).
    value 1 - number of tabstops
    values 2 to + 1 - description of a tabstop:
    absolute position of a tab stop (in space units)
    kind of tab
        l - left tab
        c - center tab
        r - decimal tab
        b - bar tab (a vertical bar, as in Word)
    kind of dot leader
        . - dotted leader
        - - dashed leader
        _ - underline leader
        = - double line leader
        t - thick-line leader
        a space - no leader
    Value + 2 - scope:
        a - all (or only) selected paragraphs have these settings
        f - the first selected paragraph has these settings, but other(s) don't
        c - the current paragraph has these settings
Failure: "" and sets the @error flag to non-zero.
@error: 101 - $hWnd is not a handle

Remarks

To enter a tab into a control, press Ctrl_Tab.

Related

_GUICtrlRichEdit_SetParaTabStops

See Also

Search EM_GETPARAFORMAT in MSDN Library.

Example

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg, $g_hRichEdit

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($g_hRichEdit, "First paragraph")
    Report("0. Para with default settings")

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($g_hRichEdit) ; needed unless script crashes
                ; GUIDelete()   ; is OK too
                Exit
            Case $iMsg = $idBtnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_AppendText($g_hRichEdit, @CRLF & "Second paragraph")
                        _GUICtrlRichEdit_SetParaTabStops($g_hRichEdit, ".3l ;1c ;2.5r.")
                        Report("1. TabStops of second paragraph")
                    Case 2
                        _GUICtrlRichEdit_SetSel($g_hRichEdit, 0, 2)
                        Report("2. Tabstops of first paragraph")
                    Case 3
                        _GUICtrlRichEdit_SetSel($g_hRichEdit, 10, 26)
                        Report("Tabstops of first paragraph in selection")
                    Case 4
                        _GUICtrlRichEdit_SetParaTabStops($g_hRichEdit, "2.3r=")
                        Report("3. Change tabstops of both paragraphs")
                    Case 5
                        ; Stream all text to the Desktop so you can look at settings in Word
                        _GUICtrlRichEdit_Deselect($g_hRichEdit)
                        _GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
                        GUICtrlSetState($idBtnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Example

Func Report($sMsg)
    $sMsg = $sMsg & @CRLF & @CRLF & "Get function returns " & @CRLF & _GUICtrlRichEdit_GetParaTabStops($g_hRichEdit)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report