Function Reference


_GUICtrlRichEdit_GetSel

Gets the low and high inter-character positions of a selection

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetSel ( $hWnd )

Parameters

$hWnd Handle to the control

Return Value

Success: an array in the format [<low>, <high>].
Failure: sets the @error flag to non-zero.
@error: 101 - $hWnd is not a handle

Remarks

The first character of the text is after inter-character position 0.
If high = low, no text is selected.

Related

_GUICtrlRichEdit_Deselect, _GUICtrlRichEdit_GetSelAA, _GUICtrlRichEdit_GetSelText, _GUICtrlRichEdit_GetTextInLine, _GUICtrlRichEdit_IsTextSelected, _GUICtrlRichEdit_SetSel

See Also

Search EM_EXGETSEL in MSDN Library.

Example

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg, $g_hRichEdit

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetSel($g_hRichEdit, 2, 10)

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($g_hRichEdit) ; needed unless script crashes
                ; GUIDelete()   ; is OK too
                Exit
            Case $iMsg = $idBtnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        Report("1. Text is selected from inter-character position")
                    Case 2
                        _GUICtrlRichEdit_Deselect($g_hRichEdit)
                        Report("2. No text is selected now")
                        GUICtrlSetState($idBtnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Example

Func Report($sMsg)
    Local $aPos = _GUICtrlRichEdit_GetSel($g_hRichEdit)
    $sMsg = $sMsg & @CRLF & @CRLF & "Get function returns " & $aPos[0] & "," & $aPos[1]
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report