Function Reference


_GUICtrlRichEdit_GetText

Get all of the text in the control

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetText ( $hWnd [, $bCrToCrLf = False [, $iCodePage = 0 [, $sReplChar = ""]]] )

Parameters

$hWnd Handle to the control
$bCrToCrLf [optional] Convert each CR to a CrLf
    True - do it
    False - don't (Default)
$iCodePage [optional] code page used in translation
Default: use system default
CP_ACP for ANSI, 1200 for Unicode
$sReplChar [optional] Character used if $iCodePage is not 1200 and a wide character cannot be represented in specified code page

Return Value

Success: the text.
Failure: "" and sets the @error flag to non-zero.
@error: 101 - $hWnd is not a handle
102 - $bCrToCrLf must be True or False
103 - $iCodePage is not a number
700 - internal error

Remarks

On success, if $sReplChar set, @extended contains whether this character was used.

Call _GUICtrlRichEdit_IsModified() to determine whether the text has changed.

Related

_GUICtrlRichEdit_AppendText, _GUICtrlRichEdit_InsertText, _GUICtrlRichEdit_IsModified, _GUICtrlRichEdit_SetText

See Also

Search EM_GETTEXTEX in MSDN Library.

Example

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg

Example()

Func Example()
    Local $hGui, $hRichEdit, $iMsg
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_AppendText($hRichEdit, @CRLF & "This is appended text.")

    Report("Text Appended: " & @CRLF & @CRLF & _GUICtrlRichEdit_GetText($hRichEdit))

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; needed unless script crashes
                ; GUIDelete()   ; is OK too
                Exit
        EndSelect
    WEnd
EndFunc   ;==>Example

Func Report($sMsg)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report