Function Reference


_GUICtrlRichEdit_PauseRedraw

Pauses redrawing of the control

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_PauseRedraw ( $hWnd )

Parameters

$hWnd Handle to the control

Return Value

Success: True.
Failure: False and sets the @error flag to non-zero.
@error: 101 - $hWnd is not a handle

Related

_GUICtrlRichEdit_ResumeRedraw

See Also

Search WM_SETREDRAW in MSDN Library.

Example

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $hRichEdit, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($hRichEdit, "First paragraph")
    _GUICtrlRichEdit_PauseRedraw($hRichEdit)
    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; needed unless script crashes
                ; GUIDelete()   ; is OK too
                Exit
            Case $iMsg = $idBtnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_SetSel($hRichEdit, 5, 2)
                        Report("1.Redraw is paused")
                    Case 2
                        _GUICtrlRichEdit_InsertText($hRichEdit, "INSERTED_2")
                        Report("2.Text is inserted at active point of selection")
                    Case 3
                        _GUICtrlRichEdit_GotoCharPos($hRichEdit, 20)
                        _GUICtrlRichEdit_InsertText($hRichEdit, "INSERTED_3")
                        Report("3.Text is inserted at insertion point and Redraw is resume")
                        _GUICtrlRichEdit_ResumeRedraw($hRichEdit)
                        GUICtrlSetState($idBtnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Example

Func Report($sMsg)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report