Function Reference


_GUICtrlRichEdit_SetBkColor

Sets the background color of the control

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetBkColor ( $hWnd [, $iBngColor = Default] )

Parameters

$hWnd Handle to the control
$iBngColor [optional] one of the following:
a number - a COLORREF value
Default keyword - the system color (default)

Return Value

Success: True.
Failure: False and sets the @error flag to non-zero.
@error: 101 - $hWnd is not a handle
1022 - $iBngColor is invalid

Remarks

If you need to create a COLORREF value from an color array use _ColorSetCOLORREF() not _ColorSetRGB().

Related

_GUICtrlRichEdit_GetBkColor

See Also

Search EM_SETBKGNDCOLOR in MSDN Library.

Example

#include <Color.au3>
#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg, $g_hRichEdit

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($g_hRichEdit, "Paragraph 1")
    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($g_hRichEdit) ; needed unless script crashes
                ; GUIDelete()   ; is OK too
                Exit
            Case $iMsg = $idBtnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_SetBkColor($g_hRichEdit, 0xE8CCCC)
                        Report("1. Colored background")
                    Case 2
                        _GUICtrlRichEdit_SetBkColor($g_hRichEdit)
                        Report("2. Back to white")
                    Case 3
                        _GUICtrlRichEdit_SetBkColor($g_hRichEdit, 0xB3B3C7)
                        Report("3. Colored background again")
                        ; Stream all text to the Desktop so you can look at settings in Word
                        _GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
                        GUICtrlSetState($idBtnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Example

Func Report($sMsg)
    Local $iBngColor = _GUICtrlRichEdit_GetBkColor($g_hRichEdit)
    Local $aRet = _ColorGetRGB($iBngColor)
    $sMsg = $sMsg & @CRLF & @CRLF & $aRet[0] & ";" & $aRet[1] & ";" & $aRet[2] & " BngColor=0x" & Hex($iBngColor)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report