Function Reference


_GUICtrlRichEdit_SetParaShading

Sets the shading of paragraph(s) in the current selection or, if no selection, of paragraphs inserted at the insertion point

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetParaShading ( $hWnd [, $iWeight = Default [, $sStyle = Default [, $sForeColor = Default [, $sBackColor = Default]]]] )

Parameters

$hWnd Handle to the control
$iWeight [optional] percent of foreground color, the rest being background color
$sStyle [optional] shading style - a string containing one of the following:
    non - none
    dhz - dark horizontal
    dvt - dark vertical
    ddd - dark down diagonal
    dud - dark up diagonal
    dgr - dark grid
    dtr - dark trellis
    lhz - light horizontal
    lvt - light vertical
    ldd - light down diagonal
    lud - light up diagonal
    lgr - light grid
    ltr - light trellis
$sForeColor [optional] one of the following:
    "blk" - black (initial value)
    "blu" - blue
    "cyn" - cyan
    "grn" - green
    "mag" - magenta
    "red" - red
    "yel" - yellow
    "whi" - white
    "dbl" - dark blue
    "dgn" - dark green
    "dmg" - dark magenta
    "drd" - dark red
    "dyl" - dark yellow
    "dgy" - dark grey
    "lgy" - light grey
$sBackColor [optional] same values as for $sForeColor

Return Value

Success: True.
Failure: False and sets the @error flag to non-zero.
@error: 101 - $hWnd is not a handle
103 - value of $sStyle is invalid
104 - value of $sForeColor is invalid
105 - value of $sBackColor is invalid
1021 - $iWeight is not a positive number
1022 - value of $iWeight is invalid
700 - operation failed

Remarks

If text is selected, the defaults are the values of the first paragraph with text selected.
If none is selected, the defaults are the values of the current paragraph.

Shading does not show in Rich Edit, but shading created here will show in Word.

Related

_GUICtrlRichEdit_GetParaShading

See Also

Search EM_SETPARAFORMAT in MSDN Library.

Example

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg, $g_hRichEdit

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($g_hRichEdit, "First paragraph")
    Report("0. Para with default settings")

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($g_hRichEdit) ; needed unless script crashes
                ; GUIDelete()   ; is OK too
                Exit
            Case $iMsg = $idBtnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_AppendText($g_hRichEdit, @CRLF & "Second paragraph")
                        _GUICtrlRichEdit_SetParaShading($g_hRichEdit, 60, "ddd", "blu", "dmg")
                        Report("1. Shading of second paragraph is ")
                    Case 2
                        _GUICtrlRichEdit_SetSel($g_hRichEdit, 0, 2)
                        Report("2. Style of first paragraph in the selection is ")
                    Case 3
                        _GUICtrlRichEdit_SetSel($g_hRichEdit, 10, 26)
                        _GUICtrlRichEdit_SetParaShading($g_hRichEdit, Default, "dgr")
                        Report("3. Change shading of both paragraphs")
                    Case 4
                        ; Stream all text to the Desktop so you can look at settings in Word
                        _GUICtrlRichEdit_Deselect($g_hRichEdit)
                        _GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
                        GUICtrlSetState($idBtnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Example

Func Report($sMsg)
    $sMsg = $sMsg & @CRLF & @CRLF & "Get function returns " & @CRLF & _GUICtrlRichEdit_GetParaShading($g_hRichEdit)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report