Scrolls the display such that ($ix,$iY) is in the upper left corner of the control
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetScrollPos ( $hWnd, $iX, $iY )
| $hWnd | Handle to the control |
| $iX | x coordinate (in pixels) |
| $iY | y coordinate (in pixels) |
| Success: | True. |
| Failure: | False and sets the @error flag to non-zero. |
| @error: | 101 - $hWnd is not a handle 102 - $iX is neither a positive number nor zero 103 - $iY is neither a positive number nor zero |
Never scrolls the text completely off the view rectangle.
Search EM_SETSCROLLPOS in MSDN Library.
#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>
Global $g_idLblMsg, $g_hRichEdit
Example()
Func Example()
Local $hGui = GUICreate("RichEdit Get/Set Scroll Pos (v" & @AutoItVersion & ")", 360, 350, -1, -1)
$g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 10, 10, 340, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
Local $idBtnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState(@SW_SHOW)
_GUICtrlRichEdit_SetText($g_hRichEdit, "Paragraph 1")
For $i = 2 To 20
_GUICtrlRichEdit_AppendText($g_hRichEdit, @CRLF & "Paragraph " & $i)
Next
Report("0. Initially scrolled to show insertion point")
Local $iMsg, $iStep = 0
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($g_hRichEdit) ; needed unless script crashes
; GUIDelete() ; is OK too
Exit
Case $iMsg = $idBtnNext
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_SetScrollPos($g_hRichEdit, 0, 0)
Report("1. Scrolled to top")
Case 2
_GUICtrlRichEdit_SetScrollPos($g_hRichEdit, 7, 22)
Report("2. Scrolled down a bit, and to the right")
GUICtrlSetState($idBtnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Example
Func Report($sMsg)
Local $aPos = _GUICtrlRichEdit_GetScrollPos($g_hRichEdit)
$sMsg = $sMsg & @CRLF & @CRLF & "Get function returns " & $aPos[0] & ";" & $aPos[1]
GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc ;==>Report