Retrieves the current widths of the horizontal and vertical borders
#include <GuiStatusBar.au3>
_GUICtrlStatusBar_GetBorders ( $hWnd )
| $hWnd | Handle to the control |
| Success: | an array with the following format: $aBorders[0] - Width of the horizontal border $aBorders[1] - Width of the vertical border $aBorders[2] - Width of the border between rectangles |
| Failure: | sets the @error flag to non-zero. |
_GUICtrlStatusBar_GetBordersHorz, _GUICtrlStatusBar_GetBordersRect, _GUICtrlStatusBar_GetBordersVert
#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>
Global $g_idMemo
Example()
Func Example()
; Create GUI
Local $hGUI = GUICreate("StatusBar Get Borders (v" & @AutoItVersion & ")", 400, 300)
Local $hStatus = _GUICtrlStatusBar_Create($hGUI)
Local $aParts[3] = [75, 150, -1]
_GUICtrlStatusBar_SetParts($hStatus, $aParts)
; Create memo control
$g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
GUISetState(@SW_SHOW)
; Get border sizes
Local $aInfo = _GUICtrlStatusBar_GetBorders($hStatus)
MemoWrite("Horizontal border width .: " & $aInfo[0])
MemoWrite("Vertical border width ...: " & $aInfo[1])
MemoWrite("Width between rectangles : " & $aInfo[2])
; Loop until the user exits.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>Example
; Write message to memo
Func MemoWrite($sMessage = "")
GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite