Function Reference


_GUICtrlStatusBar_GetUnicodeFormat

Retrieves the Unicode character format flag

#include <GuiStatusBar.au3>
_GUICtrlStatusBar_GetUnicodeFormat ( $hWnd )

Parameters

$hWnd Handle to the control

Return Value

True: the control is using Unicode characters.
False: the control is using ANSI characters.

Related

_GUICtrlStatusBar_SetUnicodeFormat

Example

#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hStatus

    ; Create GUI
    $hGUI = GUICreate("StatusBar Get Unicode Format", 400, 300)
    $hStatus = _GUICtrlStatusBar_Create($hGUI)

    ; Create memo control
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Get/Set Unicode format
    MemoWrite("Unicode format .: " & _GUICtrlStatusBar_GetUnicodeFormat($hStatus))
    _GUICtrlStatusBar_SetUnicodeFormat($hStatus, False)
    MemoWrite("Unicode format .: " & _GUICtrlStatusBar_GetUnicodeFormat($hStatus))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Write message to memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite