Function Reference


_GUICtrlTab_FindTab

Searches for a tab with the specific text

#include <GuiTab.au3>
_GUICtrlTab_FindTab ( $hWnd, $sText [, $bInStr = False [, $iStart = 0]] )

Parameters

$hWnd Control ID/Handle to the control
$sText Text to search for
$bInStr [optional] If True, the text can be anywhere in the tab's text.
$iStart [optional] 0-based index of the tab to start searching from

Return Value

Success: the 0-based tab index that matches the search.
Failure: -1.

Remarks

The search is case insensitive.

Example

#include <GUIConstantsEx.au3>
#include <GuiTab.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idTab

    ; Create GUI
    GUICreate("Tab Control Find Tab", 400, 300)
    $idTab = GUICtrlCreateTab(2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Add tabs
    _GUICtrlTab_InsertItem($idTab, 0, "Tab 1")
    _GUICtrlTab_InsertItem($idTab, 1, "Tab 2")
    _GUICtrlTab_InsertItem($idTab, 2, "Tab 3")

    ; Search for "Tab 2"
    MsgBox($MB_SYSTEMMODAL, "Information", '"Tab 2" at index ' & _GUICtrlTab_FindTab($idTab, "Tab 2"))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example