Function Reference


_GUICtrlTab_HitTest

Determines where a point lies control

#include <GuiTab.au3>
_GUICtrlTab_HitTest ( $hWnd, $iX, $iY )

Parameters

$hWnd Control ID/Handle to the control
$iX X position to test
$iY Y position to test

Return Value

Returns an array with the following format:
[0] - 0-based index of the tab, or -1 if no tab is at the position
[1] - Results of the hit test:
1 - The position is not over a tab
2 - The position is over a tab's icon
4 - The position is over a tab's text

Example

#include <GUIConstantsEx.au3>
#include <GuiTab.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $aHit, $idTab

    ; Create GUI
    GUICreate("Tab Control HitTest", 400, 300)
    $idTab = GUICtrlCreateTab(2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Add tabs
    _GUICtrlTab_InsertItem($idTab, 0, "Tab 1")
    _GUICtrlTab_InsertItem($idTab, 1, "Tab 2")
    _GUICtrlTab_InsertItem($idTab, 2, "Tab 3")

    ; Do a hit test
    $aHit = _GUICtrlTab_HitTest($idTab, 80, 10)
    MsgBox($MB_SYSTEMMODAL, "Information", "Point [80,10] is over tab " & $aHit[0])

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example