Function Reference


_GUICtrlTab_SetCurFocus

Sets the focus to a specified tab

#include <GuiTab.au3>
_GUICtrlTab_SetCurFocus ( $hWnd, $iIndex )

Parameters

$hWnd Control ID/Handle to the control
$iIndex 0-based item index

Return Value

None.

Remarks

If the tab control has the $TCS_BUTTONS style (button mode), the tab with the focus may be different from the selected tab.
For example, when a tab is selected, the user can press the arrow keys to set the focus to a different tab without changing the selected tab.
In button mode, $TCM_SETCURFOCUS sets the input focus to the button associated with the specified tab, but it does not change the selected tab.

If the tab control does not have the $TCS_BUTTONS style, changing the focus also changes the selected tab.

Related

_GUICtrlTab_GetCurFocus

Example

#include <GUIConstantsEx.au3>
#include <GuiTab.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idTab

    ; Create GUI
    GUICreate("Tab Control Set Current Focus", 400, 300)
    $idTab = GUICtrlCreateTab(2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Add tabs
    _GUICtrlTab_InsertItem($idTab, 0, "Tab 1")
    _GUICtrlTab_InsertItem($idTab, 1, "Tab 2")
    _GUICtrlTab_InsertItem($idTab, 2, "Tab 3")

    ; Get/Set current focus
    _GUICtrlTab_SetCurFocus($idTab, 1)
    MsgBox($MB_SYSTEMMODAL, "Information", "Current Focus: " & _GUICtrlTab_GetCurFocus($idTab))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example