Adds a new string to the toolbar's string pool
#include <GuiToolbar.au3>
_GUICtrlToolbar_AddString ( $hWnd, $sString )
| $hWnd | Handle to the control |
| $sString | String to add |
| Success: | 0-based index of the new string. |
| Failure: | -1. |
#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>
Example()
Func Example()
; Create GUI
Local $hGUI = GUICreate("Toolbar Ass Sring (v" & @AutoItVersion & ")", 400, 300)
Local $hToolbar = _GUICtrlToolbar_Create($hGUI)
GUISetState(@SW_SHOW)
; Set ANSI format
;~ _GUICtrlToolbar_SetUnicodeFormat($hToolbar, False)
; Add standard system bitmaps
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
; Add strings
Local $aStrings[4]
$aStrings[0] = _GUICtrlToolbar_AddString($hToolbar, "&New")
$aStrings[1] = _GUICtrlToolbar_AddString($hToolbar, "&Open")
$aStrings[2] = _GUICtrlToolbar_AddString($hToolbar, "&Save")
$aStrings[3] = _GUICtrlToolbar_AddString($hToolbar, "&Help")
; Add buttons
Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp
_GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW, $aStrings[0])
_GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN, $aStrings[1])
_GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE, $aStrings[2])
_GUICtrlToolbar_AddButtonSep($hToolbar)
_GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP, $aStrings[3])
; Loop until the user exits.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>Example