Function Reference


_GUICtrlToolbar_GetButtonStyle

Retrieves the style flags of a button

#include <GuiToolbar.au3>
_GUICtrlToolbar_GetButtonStyle ( $hWnd, $iCommandID )

Parameters

$hWnd Handle to the control
$iCommandID Button command ID

Return Value

Returns the button style. Can be a combination of the following:
$BTNS_AUTOSIZE - The toolbar control should not assign the standard width to the button
$BTNS_CHECK - Toggles between the pressed and nonpressed
$BTNS_CHECKGROUP - Button that stays pressed until another button in the group is pressed
$BTNS_DROPDOWN - Drop-down style button that can display a list
$BTNS_GROUP - Button that stays pressed until another button in the group is pressed
$BTNS_NOPREFIX - The button text will not have an accelerator prefix
$BTNS_SEP - Separator
$BTNS_SHOWTEXT - Button text should be displayed
$BTNS_WHOLEDROPDOWN - The button has a drop-down arrow

Related

_GUICtrlToolbar_SetButtonStyle

Example

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hToolbar
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    ; Create GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $g_idMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 10, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Add standard system bitmaps
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Add buttons
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Set Save button style
    _GUICtrlToolbar_SetButtonStyle($hToolbar, $e_idSave, $BTNS_CHECK)

    ; Show Save button style
    MemoWrite("Save button style: " & _GUICtrlToolbar_GetButtonStyle($hToolbar, $e_idSave))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Write message to memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite