Function Reference


_GUICtrlToolbar_IndexToCommand

Retrieves the command identifier associated with the button

#include <GuiToolbar.au3>
_GUICtrlToolbar_IndexToCommand ( $hWnd, $iIndex )

Parameters

$hWnd Handle to the control
$iIndex Button index

Return Value

Returns the button command identifier.

Related

_GUICtrlToolbar_CommandToIndex

Example

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGUI, $hToolbar, $iIndex
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    ; Create GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    GUISetState(@SW_SHOW)

    ; Add standard system bitmaps
    _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)

    ; Add buttons
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Show Save button index
    $iIndex = _GUICtrlToolbar_CommandToIndex($hToolbar, $e_idSave)
    MsgBox($MB_SYSTEMMODAL, "Information", "Save button index .: " & $iIndex)
    MsgBox($MB_SYSTEMMODAL, "Information", "Save button command .: " & _GUICtrlToolbar_IndexToCommand($hToolbar, $iIndex))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example