Sets the size of the buttons to be added to a toolbar
#include <GuiToolbar.au3>
_GUICtrlToolbar_SetButtonSize ( $hWnd, $iHeight, $iWidth )
| $hWnd | Handle to the control |
| $iHeight | Height, in pixels, of the buttons |
| $iWidth | Width, in pixels, of the buttons |
| Success: | True. |
| Failure: | False. |
The size can be set only before adding any buttons to the toolbar. If an application does not explicitly set the button size, the size defaults to 24 by 22 pixels.
#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>
Global $g_idMemo
Example()
Func Example()
Local $hGUI, $hToolbar, $aSize
Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp
; Create GUI
$hGUI = GUICreate("Toolbar", 400, 300)
$hToolbar = _GUICtrlToolbar_Create($hGUI)
$g_idMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
GUICtrlSetFont($g_idMemo, 10, 400, 0, "Courier New")
GUISetState(@SW_SHOW)
; Add standard system bitmaps
Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
Case 0
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
Case 2
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
EndSwitch
; Add buttons
_GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
_GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
_GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
_GUICtrlToolbar_AddButtonSep($hToolbar)
_GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)
; Show button size
$aSize = _GUICtrlToolbar_GetButtonSize($hToolbar)
MemoWrite("Button height : " & $aSize[0])
MemoWrite("Button width .: " & $aSize[1])
_GUICtrlToolbar_SetButtonSize($hToolbar, $aSize[0], $aSize[1] + 10)
$aSize = _GUICtrlToolbar_GetButtonSize($hToolbar)
MemoWrite("New Button Size")
MemoWrite("Button height : " & $aSize[0])
MemoWrite("Button width .: " & $aSize[1])
; Loop until the user exits.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>Example
; Write message to memo
Func MemoWrite($sMessage = "")
GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite