Function Reference

_GUICtrlToolbar_SetStyle

Sets the style control

#include <GuiToolbar.au3>
_GUICtrlToolbar_SetStyle ( $hWnd, $iStyle )

Parameters

$hWnd Handle to the control
$iStyle Control styles. Can be a combination of the following:
    $TBSTYLE_TOOLTIPS - Creates a ToolTip control
    $TBSTYLE_WRAPABLE - Creates a toolbar that can have multiple lines of buttons
    $TBSTYLE_ALTDRAG - Allows users to change a toolbar button's position by dragging it
    $TBSTYLE_FLAT - Creates a flat toolbar
    $TBSTYLE_LIST - Creates a flat toolbar with button text to the right of the bitmap
    $TBSTYLE_CUSTOMERASE - Sends $NM_CUSTOMDRAW messages when processing $WM_ERASEBKGND messages
    $TBSTYLE_REGISTERDROP - Sends $TBN_GETOBJECT messages to request drop target objects
    $TBSTYLE_TRANSPARENT - Creates a transparent toolbar

Return Value

None.

Related

_GUICtrlToolbar_GetStyle

Example

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
        Local $hGUI, $hToolbar
        Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

        ; Create GUI
        $hGUI = GUICreate("Toolbar", 400, 300)
        $hToolbar = _GUICtrlToolbar_Create($hGUI)
        $g_idMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
        GUICtrlSetFont($g_idMemo, 10, 400, 0, "Courier New")
        GUISetState(@SW_SHOW)

        ; Set control style
        _GUICtrlToolbar_SetStyle($hToolbar, BitOR($TBSTYLE_LIST, $CCS_TOP))

        ; Add standard system bitmaps
        Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
                Case 0
                        _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
                Case 2
                        _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
        EndSwitch

        ; Add buttons
        _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
        _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
        _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
        _GUICtrlToolbar_AddButtonSep($hToolbar)
        _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

        ; Show control style
        MemoWrite("Toolbar style .: 0x" & Hex(_GUICtrlToolbar_GetStyle($hToolbar)))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Write message to memo
Func MemoWrite($sMessage = "")
        GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite