Function Reference


_GUICtrlTreeView_SetState

Set the state of the specified item

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetState ( $hWnd, $hItem [, $iState = 0 [, $bSetState = True]] )

Parameters

$hWnd Control ID/Handle to the control
$hItem Handle to the item
$iState [optional] The new item state, can be one or more of the following:
    $TVIS_SELECTED - Set item selected
    $TVIS_CUT - Set item as part of a cut-and-paste operation
    $TVIS_DROPHILITED - Set item as a drag-and-drop target
    $TVIS_BOLD - Set item as bold
    $TVIS_EXPANDED - Expand item
    $TVIS_EXPANDEDONCE - Set item's list of child items has been expanded at least once
    $TVIS_EXPANDPARTIAL - Set item as partially expanded
$bSetState [optional] True if item state is to be set, False remove item state

Return Value

Success: True.
Failure: False.

Remarks

State values can BitOR'ed together as for example BitOR($TVIS_SELECTED, $TVIS_BOLD).

Related

_GUICtrlTreeView_GetState

Example

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $a_hItem[10], $hImage, $iImage, $iRand, $idTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Set State", 400, 300)

    $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 146)
    _GUICtrlTreeView_SetNormalImageList($idTreeView, $hImage)

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    For $x = 0 To 9
        $iImage = Random(0, 5, 1)
        $a_hItem[$x] = _GUICtrlTreeView_Add($idTreeView, 0, StringFormat("[%02d] New Item", $x), $iImage, $iImage)
        For $y = 1 To Random(2, 10, 1)
            $iImage = Random(0, 5, 1)
            _GUICtrlTreeView_AddChild($idTreeView, $a_hItem[$x], StringFormat("[%02d] New Child", $y), $iImage, $iImage)
        Next
    Next
    _GUICtrlTreeView_EndUpdate($idTreeView)

    $iRand = Random(0, 9, 1)
    _GUICtrlTreeView_SetState($idTreeView, $a_hItem[$iRand], BitOR($TVIS_BOLD, $TVIS_EXPANDED)) ; set bold and just the expanded "-" not really expanded
    _GUICtrlTreeView_SetState($idTreeView, $a_hItem[$iRand], $TVIS_BOLD, False) ; reset just Bold state
    MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("State for Index %d: %s", $iRand, _GUICtrlTreeView_GetState($idTreeView, $a_hItem[$iRand])))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example