Function Reference


_GUIScrollBars_GetScrollBarXYThumbTop

Retrieves the Position of the top or left of the thumb

#include <GuiScrollBars.au3>
_GUIScrollBars_GetScrollBarXYThumbTop ( $hWnd, $iObject )

Parameters

$hWnd Handle to the window
$iObject Specifies the scroll bar object. This parameter can be one of the following values:
    $OBJID_CLIENT - The $hWnd parameter is a handle to a scroll bar control.
    $OBJID_HSCROLL - The horizontal scroll bar of the $hWnd window.
    $OBJID_VSCROLL - The vertical scroll bar of the $hWnd window.

Return Value

Success: the position of the top or left of the thumb.
Failure: sets the @error flag to non-zero.

Related

_GUIScrollBars_GetScrollBarInfoEx

Example

#include <GUIConstantsEx.au3>
#include <GuiScrollBars.au3>
#include <StructureConstants.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
        Local $hGUIMsg, $hGUI

        $hGUI = GUICreate("ScrollBar Example", 400, 400, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_SIZEBOX))
        $g_idMemo = GUICtrlCreateEdit("", 2, 2, 380, 380, BitOR($WS_HSCROLL, $WS_VSCROLL))
        GUICtrlSetResizing($g_idMemo, $GUI_DOCKALL)
        GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
        GUISetBkColor(0x88AABB)

        GUISetState(@SW_SHOW)

        _GUIScrollBars_Init($hGUI)

        MemoWrite("Horizontal" & @CRLF & "--------------------------------------")
        MemoWrite("Left of thumb: " & _GUIScrollBars_GetScrollBarXYThumbTop($hGUI, $OBJID_HSCROLL))
        MemoWrite("Right of thumb: " & _GUIScrollBars_GetScrollBarXYThumbBottom($hGUI, $OBJID_HSCROLL) & @CRLF)

        MemoWrite("Vertical" & @CRLF & "--------------------------------------")
        MemoWrite("Top of thumb: " & _GUIScrollBars_GetScrollBarXYLineButton($hGUI, $OBJID_VSCROLL))
        MemoWrite("Bottom of thumb: " & _GUIScrollBars_GetScrollBarXYThumbBottom($hGUI, $OBJID_VSCROLL))

        While 1
                $hGUIMsg = GUIGetMsg()

                Switch $hGUIMsg
                        Case $GUI_EVENT_CLOSE
                                ExitLoop
                EndSwitch
        WEnd

        Exit
EndFunc   ;==>Example

; Write a line to the memo control
Func MemoWrite($sMessage)
        GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite