Function Reference


_SoundClose

Closes a sound previously opened with _SoundOpen

#include <Sound.au3>
_SoundClose ( $aSndID )

Parameters

$aSndID Sound ID array as returned by _SoundOpen()

Return Value

Success: 1.
Failure: 0 and sets the @error flag to non-zero.
@error: 1 = Failure
3 = Invalid Sound ID. Use return array from _SoundOpen().

Related

_SoundOpen

Example

#include <MsgBoxConstants.au3>
#include <Sound.au3>

Local $aSound = _SoundOpen(@WindowsDir & "\media\tada.wav")
If @error = 2 Then
    MsgBox($MB_SYSTEMMODAL, "Error", "The file does not exist")
    Exit
ElseIf @extended <> 0 Then
    Local $iExtended = @extended ; Assign because @extended will be set after DllStructCreate().
    Local $tText = DllStructCreate("char[128]")
    DllCall("winmm.dll", "short", "mciGetErrorStringA", "str", $iExtended, "struct*", $tText, "int", 128)
    MsgBox($MB_SYSTEMMODAL, "Error", "The open failed." & @CRLF & "Error Number: " & $iExtended & @CRLF & "Error Description: " & DllStructGetData($tText, 1) & @CRLF & "Please Note: The sound may still play correctly.")
Else
    MsgBox($MB_SYSTEMMODAL, "Success", "The file opened successfully")
EndIf

If _SoundClose($aSound) Then
    MsgBox($MB_SYSTEMMODAL, "Success", "The sound was closed successfully")
Else
    MsgBox($MB_SYSTEMMODAL, "Error", "The file was not closed successfully")
EndIf