Function Reference


_Date_Time_FileTimeToSystemTime

Converts a file time to system time format

#include <Date.au3>
_Date_Time_FileTimeToSystemTime ( $tFileTime )

Parameters

$tFileTime a $tagFILETIME structure containing the file time to convert to system date and time format or a pointer to it.

Return Value

Returns a $tagSYSTEMTIME structure that contains the converted file time.

Related

$tagFILETIME, $tagSYSTEMTIME, _Date_Time_FileTimeToDOSDateTime, _Date_Time_FileTimeToLocalFileTime

Example

#include <Date.au3>
#include <FontConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
        Local $tFile, $tSystem

        ; Create GUI
        GUICreate("Time", 400, 300)
        $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
        GUICtrlSetFont($g_idMemo, 9,  $FW_NORMAL, $GUI_FONTNORMAL, "Courier New")
        GUISetState(@SW_SHOW)

        ; Encode a file time
        $tFile = _Date_Time_EncodeFileTime(@MON, @MDAY, @YEAR, @HOUR, @MIN, @SEC)
        $tSystem = _Date_Time_FileTimeToSystemTime($tFile)
        MemoWrite("System file time .: " & _Date_Time_SystemTimeToDateTimeStr($tSystem))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Write a line to the memo control
Func MemoWrite($sMessage)
        GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite