Function Reference


_Date_Time_LocalFileTimeToFileTime

Converts a local file time to a file time based on UTC

#include <Date.au3>
_Date_Time_LocalFileTimeToFileTime ( $tLocalTime )

Parameters

$tLocalTime a $tagFILETIME structure that specifies the local file time to be converted into a UTC based file time or a pointer to it.

Return Value

Returns a $tagFILETIME structure with the converted UTC based file time.

Remarks

This function uses the current settings for the time zone and daylight saving time. Therefore, if it is daylight saving time, this function will take daylight saving time into account, even if the time you are converting is in standard time.

Related

$tagFILETIME, _Date_Time_FileTimeToLocalFileTime

Example

#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $tTime, $tLocal

    ; Create GUI
    GUICreate("Time", 400, 300)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Show local date/time as UTC
    $tTime = _Date_Time_EncodeFileTime(@MON, @MDAY, @YEAR, @HOUR, @MIN, @SEC)
    $tLocal = _Date_Time_LocalFileTimeToFileTime($tTime)
    MemoWrite("Local date/time .: " & _Date_Time_FileTimeToStr($tLocal))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Write a line to the memo control
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite