Function Reference


_GUICtrlComboBoxEx_GetEditControl

Gets the handle to the edit control portion of a ComboBoxEx control

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_GetEditControl ( $hWnd )

Parameters

$hWnd Handle to the control

Return Value

Returns the handle to the edit control within the ComboBoxEx control if it uses the $CBS_DROPDOWN style.

Example

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGUI, $hImage, $hCombo

    ; Create GUI
    $hGUI = GUICreate("ComboBoxEx Get Edit Control", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
    _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

    For $x = 0 To 5
        _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Random string", Random(1, 100, 1)), $x)
    Next

    MsgBox($MB_SYSTEMMODAL, "Information", _
            "Combo Control Handle: " & _GUICtrlComboBoxEx_GetComboControl($hCombo) & @CRLF & _
            "Edit Control Handle: " & _GUICtrlComboBoxEx_GetEditControl($hCombo))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example