Function Reference


_GUICtrlComboBoxEx_GetItemSelectedImage

Retrieves the index of the item's selected image icon

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_GetItemSelectedImage ( $hWnd, $iIndex )

Parameters

$hWnd Handle to the control
$iIndex 0-based item index

Return Value

Success: a 0-based item selected image index.
Failure: -1.

Related

_GUICtrlComboBoxEx_SetItemSelectedImage

Example

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
        ; Create GUI
        Local $hGUI = GUICreate("ComboBoxEx Get/Set Item Selected Image (v" & @AutoItVersion & ")", 400, 300)
        Local $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
        GUISetState(@SW_SHOW)

        Local $hImage = _GUIImageList_Create(16, 16, 5, 3)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
        _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

        _GUICtrlComboBoxEx_BeginUpdate($hCombo)
        Local $iImage
        For $x = 0 To 149
                $iImage = Random(0, 8, 1)
                _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : string", $x), $iImage, $iImage)
        Next
        _GUICtrlComboBoxEx_EndUpdate($hCombo)

        _GUICtrlComboBoxEx_SetItemImage($hCombo, 0, 1)
        _GUICtrlComboBoxEx_SetItemIndent($hCombo, 1, 1)
        _GUICtrlComboBoxEx_SetItemIndent($hCombo, 2, 1)
        _GUICtrlComboBoxEx_SetItemSelectedImage($hCombo, 0, 3)
        MsgBox($MB_SYSTEMMODAL, "Information", "Item Selected Image: " & _GUICtrlComboBoxEx_GetItemSelectedImage($hCombo, 0))

        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example