Set the maximum allowable width, in pixels, of the ListBox of a ComboBox
#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_SetDroppedWidth ( $hWnd, $iWidth )
| $hWnd | Handle to the control |
| $iWidth | The width of the ListBox, in pixels |
| Success: | the new width of the ListBox. |
| Failure: | -1. |
By default, the minimum allowable width of the drop-down ListBox is zero.
The width of the ListBox is either the minimum allowable width or the ComboBox width, whichever is larger.
Use $CBS_DROPDOWN or $CBS_DROPDOWNLIST style.
_GUICtrlComboBoxEx_GetDroppedWidth
#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
Global $g_idMemo
Example()
Func Example()
; Create GUI
Local $hGUI = GUICreate("ComboBoxEx Get/Set Dropped Width (v" & @AutoItVersion & ")", 400, 300)
Local $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
$g_idMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
GUISetState(@SW_SHOW)
Local $hImage = _GUIImageList_Create(16, 16, 5, 3)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
_GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
_GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)
For $x = 0 To 8
_GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : string", $x), $x, $x)
Next
; get dropped width
MemoWrite("Dropped Width......: " & _GUICtrlComboBoxEx_GetDroppedWidth($hCombo))
Sleep(500)
; show drop down
_GUICtrlComboBoxEx_ShowDropDown($hCombo, True)
Sleep(500)
; hide drop down
_GUICtrlComboBoxEx_ShowDropDown($hCombo)
; set Dropped Width
_GUICtrlComboBoxEx_SetDroppedWidth($hCombo, 500)
Sleep(500)
; get dropped width
MemoWrite("Dropped Width......: " & _GUICtrlComboBoxEx_GetDroppedWidth($hCombo))
Sleep(500)
; show drop down
_GUICtrlComboBoxEx_ShowDropDown($hCombo, True)
Sleep(500)
; hide drop down
_GUICtrlComboBoxEx_ShowDropDown($hCombo)
; Loop until the user exits.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>Example
; Write a line to the memo control
Func MemoWrite($sMessage)
GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite