Function Reference


_GUICtrlComboBoxEx_SetItemHeight

Set the height of list items or the selection field in a ComboBox

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_SetItemHeight ( $hWnd, $iComponent, $iHeight )

Parameters

$hWnd Handle to the control
$iComponent Use the following values:
    –1 - Set the height of the selection field
    0 - Set the height of list items
$iHeight The height, in pixels, of the combo box component identified by $iComponent

Return Value

Success: 0.
Failure: -1 if height is invalid.

Related

_GUICtrlComboBoxEx_GetItemHeight

Example

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hImage, $hCombo

    ; Create GUI
    $hGUI = GUICreate("ComboBoxEx Set Item Height", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
    $g_idMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

    For $x = 0 To 8
        _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Random string", Random(1, 100, 1)), $x, $x)
    Next

    MemoWrite("Set Item Height: " & _GUICtrlComboBoxEx_SetItemHeight($hCombo, -1, 18))
    MemoWrite("Item Height: " & _GUICtrlComboBoxEx_GetItemHeight($hCombo, -1))
    MemoWrite("Set Item Height: " & _GUICtrlComboBoxEx_SetItemHeight($hCombo, 0, 20))
    MemoWrite("Item Height: " & _GUICtrlComboBoxEx_GetItemHeight($hCombo, 0))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Write a line to the memo control
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite