Function Reference


_GUICtrlComboBoxEx_SetMinVisible

Set the minimum number of visible items in the drop-down list of a ComboBox

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_SetMinVisible ( $hWnd, $iMinimum )

Parameters

$hWnd Handle to the control
$iMinimum Specifies the minimum number of visible items

Return Value

Success: True.
Failure: False.

Remarks

When the number of items in the drop-down list is greater than the minimum, the Combobbox uses a scrollbar. By default, 30 is the minimum number of visible items.

This message is ignored if the combo box control has style $CBS_NOINTEGRALHEIGHT.

Related

_GUICtrlComboBoxEx_GetMinVisible

Example

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGUI, $hImage, $iImage, $hCombo

    ; Create GUI
    $hGUI = GUICreate("ComboBoxEx Set Min Visible", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
    GUISetState(@SW_SHOW)

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

    _GUICtrlComboBoxEx_InitStorage($hCombo, 150, 300)
    _GUICtrlComboBoxEx_BeginUpdate($hCombo)

    For $x = 0 To 149
        $iImage = Random(0, 8, 1)
        _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Random string", Random(1, 100, 1)), $iImage, $iImage)
    Next
    _GUICtrlComboBoxEx_EndUpdate($hCombo)

    MsgBox($MB_SYSTEMMODAL, "Information", "Min Vis.: " & _GUICtrlComboBoxEx_GetMinVisible($hCombo))
    MsgBox($MB_SYSTEMMODAL, "Information", "Set Min Vis: " & _GUICtrlComboBoxEx_SetMinVisible($hCombo, 50))
    MsgBox($MB_SYSTEMMODAL, "Information", "Min Vis.: " & _GUICtrlComboBoxEx_GetMinVisible($hCombo))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example