Function Reference


_GUICtrlComboBox_SetExtendedUI

Select either the default user interface or the extended user interface

#include <GuiComboBox.au3>
_GUICtrlComboBox_SetExtendedUI ( $hWnd [, $bExtended = False] )

Parameters

$hWnd Control ID/Handle to the control
$bExtended [optional] Specifies whether the combo box uses the extended

Return Value

Success: True.
Failure: False.

Remarks

By default, the F4 key opens or closes the list and the DOWN ARROW changes the current selection.

In a ComboBox with the extended user interface, the F4 key is disabled and pressing the DOWN ARROW key opens the drop-down list.

Related

_GUICtrlComboBox_GetExtendedUI

Example

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>

Global $g_idMemo

Example()

Func Example()
        ; Create GUI
        GUICreate("ComboBox Get/Set ExtendedUI (v" & @AutoItVersion & ")", 400, 296)
        Local $idCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
        $g_idMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
        GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
        GUISetState(@SW_SHOW)

        ; Add files
        _GUICtrlComboBox_BeginUpdate($idCombo)
        _GUICtrlComboBox_AddDir($idCombo, @WindowsDir & "\*.exe")
        _GUICtrlComboBox_EndUpdate($idCombo)

        ; Get Extended UI
        MemoWrite("Extended UI: " & _GUICtrlComboBox_GetExtendedUI($idCombo))

        ; Set Extended UI
        _GUICtrlComboBox_SetExtendedUI($idCombo, True)

        ; Get Extended UI
        MemoWrite("Extended UI: " & _GUICtrlComboBox_GetExtendedUI($idCombo))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
EndFunc   ;==>Example

; Write a line to the memo control
Func MemoWrite($sMessage)
        GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite