Function Reference


_GUICtrlListBox_GetListBoxInfo

Retrieve the number of items per column in a specified list box

#include <GuiListBox.au3>
_GUICtrlListBox_GetListBoxInfo ( $hWnd )

Parameters

$hWnd Control ID/Handle to the control

Return Value

Returns the number of items per column.

Example

#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idListBox

    ; Create GUI
    GUICreate("List Box Get ListBox Info", 400, 296)
    $idListBox = GUICtrlCreateList("", 2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Add strings
    _GUICtrlListBox_BeginUpdate($idListBox)
    For $iI = 1 To 9
        _GUICtrlListBox_AddString($idListBox, StringFormat("%03d : Random string", Random(1, 100, 1)))
    Next
    _GUICtrlListBox_EndUpdate($idListBox)

    ; Show items per column
    MsgBox($MB_SYSTEMMODAL, "Information", "Items per column: " & _GUICtrlListBox_GetListBoxInfo($idListBox))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example