Function Reference


_GUICtrlListBox_GetText

Returns the item (string) at the specified index

#include <GuiListBox.au3>
_GUICtrlListBox_GetText ( $hWnd, $iIndex )

Parameters

$hWnd Control ID/Handle to the control
$iIndex Specifies the 0-based index of the string to retrieve

Return Value

Returns the item (string).

Related

_GUICtrlListBox_GetTextLen

Example

#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idListBox

    ; Create GUI
    GUICreate("List Box Get Text", 400, 296)
    $idListBox = GUICtrlCreateList("", 2, 2, 396, 296, BitOR($LBS_STANDARD, $LBS_EXTENDEDSEL))
    GUISetState(@SW_SHOW)

    ; Add strings
    _GUICtrlListBox_BeginUpdate($idListBox)
    For $iI = 1 To 9
        _GUICtrlListBox_AddString($idListBox, StringFormat("%03d : Random string", Random(1, 100, 1)))
    Next
    _GUICtrlListBox_EndUpdate($idListBox)

    ; Show item text
    MsgBox($MB_SYSTEMMODAL, "Information", "Item 5 Text: " & _GUICtrlListBox_GetText($idListBox, 4))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example