Function Reference


_GUICtrlListBox_SetCurSel

Select a string and scroll it into view, if necessary

#include <GuiListBox.au3>
_GUICtrlListBox_SetCurSel ( $hWnd, $iIndex )

Parameters

$hWnd Control ID/Handle to the control
$iIndex Specifies the 0-based index of the string that is selected.
If this parameter is -1 the list box is set to have no selection.

Return Value

Success: True.
Failure: False.

Remarks

Use this message only with single-selection list boxes.
You cannot use it to set or remove a selection in a multiple-selection list box.

Related

_GUICtrlListBox_GetCurSel

Example

#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>
#include <WinAPIError.au3>

Example()

Func Example()
        ; Create GUI
        GUICreate("List Box Get/Set Cur Sel (v" & @AutoItVersion & ")", 400, 296)
        Local $idListBox = GUICtrlCreateList("", 2, 2, 396, 296)
        GUISetState(@SW_SHOW)

        ; Add strings
        _GUICtrlListBox_BeginUpdate($idListBox)
        For $iI = 0 To 9
                _GUICtrlListBox_AddString($idListBox, StringFormat("%03d : Random string", $iI))
        Next
        _GUICtrlListBox_EndUpdate($idListBox)

        ; Select an item
        _GUICtrlListBox_SetCurSel($idListBox, 4)

        ; Get currently selected item
        _WinAPI_ShowMsg("Current selection: " & _GUICtrlListBox_GetCurSel($idListBox))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
EndFunc   ;==>Example