Function Reference


_GUICtrlMonthCal_GetMonthRangeMin

Retrieves date information that represents the low limit of the controls display

#include <GuiMonthCal.au3>
_GUICtrlMonthCal_GetMonthRangeMin ( $hWnd [, $bPartial = False] )

Parameters

$hWnd Control ID/Handle to the control
$bPartial [optional] Specifies the scope of the range limits to be retrieved:
    True - Preceding and trailing months are included
    False - Only months that are entirely displayed are included

Return Value

Returns a $tagSYSTEMTIME structure.

Related

$tagSYSTEMTIME, _GUICtrlMonthCal_GetMonthRange, _GUICtrlMonthCal_GetMonthRangeMax, _GUICtrlMonthCal_GetMonthRangeMinStr

Example

#include <GUIConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $tMin, $tMax, $idMonthCal

    ; Create GUI
    GUICreate("Month Calendar Get Month Range Min", 400, 300)
    $idMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, BitOR($WS_BORDER, $MCS_MULTISELECT), 0x00000000)

    ; Create memo control
    $g_idMemo = GUICtrlCreateEdit("", 4, 168, 392, 128, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Get month range
    $tMin = _GUICtrlMonthCal_GetMonthRangeMin($idMonthCal)
    $tMax = _GUICtrlMonthCal_GetMonthRangeMax($idMonthCal)
    MemoWrite("Month range minimum: " & StringFormat("%02d/%02d/%04d", DllStructGetData($tMin, "Month"), _
            DllStructGetData($tMin, "Day"), _
            DllStructGetData($tMin, "Year")))
    MemoWrite("Month range maximum: " & StringFormat("%02d/%02d/%04d", DllStructGetData($tMax, "Month"), _
            DllStructGetData($tMax, "Day"), _
            DllStructGetData($tMax, "Year")))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Write message to memo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite